iZinked/iZpl/build.gradle

evaluationDependsOn(':iZplPlugins:GameRadio')
evaluationDependsOn(':iZplPlugins:WMP')
evaluationDependsOn(':iZplPlugins:Editor')
evaluationDependsOn(':iZplPlugins:rtsslink')
defaultTasks 'distZip'

apply plugin: 'java'
apply plugin: 'application'
apply from: "$rootDir/utils/IO.gradle"

version = '0.9.0.0-snapshot'
mainClassName = 'de.nplusc.izc.iZpl.Main'
//'de.nplusc.izc.iZpl.Main'

jar{
    manifest{
        attributes 'Implementation-Title': 'iZPlaylist',
					'Implementation-Version': version,
					'Main-Class': 'de.nplusc.izc.iZpl.Main'
					
    }
}

startScripts << { 

  def startScriptDir = outputDir.getAbsolutePath()
  def winStartScript = startScriptDir + "/" + applicationName + ".bat"
  def winStartScriptCopy = startScriptDir + "/" + applicationName + "c.bat"
  def overwriteExistingFile = true
  copyFile(winStartScript, winStartScriptCopy, overwriteExistingFile)

  //:init
  
  modifyFile(winStartScript) {
    // javaw.exe doesn't have a console
    if(it.contains("java.exe")){
      return it.replace("java.exe", "javaw.exe")
    }
    // Command that launches the app
    else if(it.startsWith("\"%JAVA_EXE%\" %DEFAULT_JVM_OPTS%")){
      return "start \"\" /b " + it
    }
    else if(it.startsWith(":init"))
    {
        //HACK
        return it+"\n"+"set VLC_PLUGIN_PATH=%APP_HOME%\\lib\\vlcbinaries\\plugins"
    }
    // Leave the line unchanged
    else{
      return it
    }
  }
  modifyFile(winStartScriptCopy) {
    if(it.startsWith(":init"))
    {
    //HACK
        return it+"\n"+"set VLC_PLUGIN_PATH=%APP_HOME%\\lib\\vlcbinaries\\plugins" 
    }
    // Leave the line unchanged
    else{
      return it
    }
  }
}
distZip {
  // Include the additional start script
  into(project.name+"-"+project.version+"/bin/"){
    from(startScripts.outputDir)
	include '*c.bat'
  }
  into(project.name+"-"+project.version+"/plugins/"){
        from project(':iZplPlugins:GameRadio').jar
        from project(':iZplPlugins:WMP').jar
        from project(':iZplPlugins:Editor').jar
        from project(':iZplPlugins:rtsslink').jar
  }
}






sourceSets{
    main{
        resources{
            exclude '**/*.xcf'
        }
    }
}
dependencies{
    compile fileTree(dir: 'lib', include: '*.jar')
    compile "net.rubygrapefruit:native-platform:0.9"
    compile "commons-io:commons-io:2.+"
    compile 'org.apache.commons:commons-exec:1.3'
    compile "org.yaml:snakeyaml:1.14"
    compile "commons-net:commons-net:3.3"
    compile 'uk.co.caprica:vlcj:+'
    compile 'com.googlecode.mp4parser:isoparser:1.0-RC-1'
    compile 'de.schlichtherle.truezip:truezip-file:7.7.7'
    compile 'de.schlichtherle.truezip:truezip-driver-zip:7.7.7'
    compile 'de.schlichtherle.truezip:truezip-driver-file:7.7.7'
    compile 'de.schlichtherle.truezip:truezip-driver-tar:7.7.7'
    compile 'de.schlichtherle.truezip:truezip-kernel:7.7.7'
    compile 'de.schlichtherle.truezip:truezip-path:7.7.7'
    compile 'de.schlichtherle.truezip:truezip-driver-tzp:7.7.7'
    compile 'de.schlichtherle.truezip:truezip-driver-http:7.7.7'
    compile 'commons-cli:commons-cli:1.3'
	compile group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.1'
	compile group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.1'
	compile group: 'org.apache.logging.log4j', name: 'log4j-iostreams', version: '2.1'
    compile group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.1'
    compile 'org.fusesource.jansi:jansi:1.11'
    compile 'org.jgrapht:jgrapht-core:0.9.0'
    compile(project(':ToolKit')) {
        transitive = false
    }
    compile(project(':izpl-shared')) {
        transitive = false
    }
}