iZinked/WPCMGr/build.gradle

defaultTasks 'distZip'

apply plugin: 'java-library'
apply plugin: 'application'
apply from: "$rootDir/utils/IO.gradle"

sourceCompatibility = 1.8
version = 'SNAPSHOT'
mainClassName = 'de.nplusc.izc.Utilities.WPCMgr.Main'


jar{
	manifest{
		attributes 'Implementation-Title': 'WPCMgr',
					'Implementation-Version': 'SNAPSHOT',
					'Main-Class': 'de.nplusc.izc.iZpl.Builder'
					
	}
}

repositories{
	mavenCentral()
}

compileJava {
options.compilerArgs << '-Xlint:none'

options.compilerArgs << '-Xlint:-deprecation'

options.compilerArgs << '-XDignore.symbol.file'
}
startScripts {
    doLast {
      def startScriptDir = outputDir.getAbsolutePath()
      def winStartScript = startScriptDir + "/" + applicationName + ".bat"
      def winStartScriptCopy = startScriptDir + "/" + applicationName + "c.bat"
      def overwriteExistingFile = true
      copyFile(winStartScript, winStartScriptCopy, overwriteExistingFile)

      modifyFile(winStartScript) {
        // javaw.exe doesn't have a console
        if(it.contains("java.exe")){
          return it.replace("java.exe", "javaw.exe")
        }
        // Command that launches the app
        else if(it.startsWith("\"%JAVA_EXE%\" %DEFAULT_JVM_OPTS%")){
          return "start \"\" /b " + it
        }
        // Leave the line unchanged
        else{
          return it
        }
      }
    }
}
distZip {
  // Include the additional start script
  into(project.name+"-"+project.version+"/bin/"){
    from(startScripts.outputDir)
	include '*c.bat'
  }
  duplicatesStrategy = 'include'
}

dependencies{
	api fileTree(dir: 'lib', include: '*.jar')
        //api "net.rubygrapefruit:native-platform:0.9"
	api "commons-io:commons-io:2.+"
	api 'org.apache.commons:commons-exec:1.3'
	api "org.yaml:snakeyaml:+"
	api 'org.ini4j:ini4j:0.5.2'
	api 'mysql:mysql-connector-java:5.1.6'
    api group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.+'
	api group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.+'
	api group: 'org.apache.logging.log4j', name: 'log4j-iostreams', version: '2.+'
    api 'org.fusesource.jansi:jansi:1.11'
    api 'commons-cli:commons-cli:1.3'
	api(project(':ToolKit')) {
        transitive = false
        
    }
    api(project(':external:java-progressbar'))
    api 'net.java.dev.jna:jna:4.1.0'
    api 'net.java.dev.jna:jna-platform:4.1.0'


	
}